Finish
/Clear
/TITLE,2-D Two-Storyreinforcement problem - Maximize fundamental frequency
A=0.25 !Prepare Model
B=5
C=0.375
D=8
E=3.75
/PREP7
K,1
K,2,C
K,3,C+A
K,4,B/2
K,5,,E
K,6,C,E
K,7,C+A,E
K,8,B/2,E
KSEL,S,,,5,8
KGEN,2,ALL,,,,A
KSEL,S,,,9,12
KGEN,2,ALL,,,,E
KSEL,S,,,13,16
KGEN,2,ALL,,,,A
ALLSEL
A,1,2,6,5
A,5,6,10,9
A,9,10,14,13
A,13,14,18,17
A,2,3,7,6
A,6,7,11,10
A,10,11,15,14
A,14,15,19,18
A,3,4,8,7
A,7,8,12,11
A,11,12,16,15
A,15,16,20,19
ET,1,82 ! Define two element type regions
ET,2,82 !1 - optimized region
ASEL,S,,,4,8 !2 - non-optimized region
ASEL,A,,,10,12,2
TYPE,2
ESIZE,0.1
AMESH,ALL
ASEL,INVE
TYPE,1
AMESH,ALL
ALLSEL
MP,EX,1,100 ! Material of structure
MP,NUXY,1,0.3
MP,DENS,1,1.0E-6
MP,EX,2,100 ! Material of concentrated masses
MP,NUXY,2,0.3
MP,DENS,2,5.0E-6
ASEL,S,,,6,8,2
ESlA,S,1
EMODIF,ALL,MAT,2 ! Define concentrated masses
ALLSEL
LOCAL,11,0,2.5
ARSYM,X,ALL ! Full model
NUMM,KP
NUMM,ELEM
NUMM,NODE
LSEL,S,,,14
LSEL,A,,,45
NSLL,S,1
D,ALL,ALL
ALLSEL
TOFREQ,FREQ1,SING,1 !Define single frequency function (1st)
TOVAR,FREQ1,OBJ ! Define objective for topological optimization
TOVAR,VOLUME,CON,,14,ACTUAL ! Define volume constraint (upper bound = 14)
TOTYPE,SCP ! Select ScP solution approach !
TODEF,0.00001 !Initialize topological optimization process,accuracy = 0.00001
TOLOOP,40,1 !Perform up to 40 iterations
FINISH
TOPLOT,1 !Plot final pseudo-densities
TOGRAPH,OBJ !Graph final objective (1st frequency) history
TOGRAPH,CON !Graph final constraint (volume) history