ANSYS单元BEAM189计算结果十分丰富，教你搞定头疼的结果提取问题
BEAM189单元被广泛应用于杆系结构中，且该单元的计算结果十分丰富。然而，在后处理时经常被复杂的结果提取或输出所羁绊，十分令人头痛。本文结合实例，详细介绍BEAM189的单元结果提取方法和技巧。
为与单元节点等区分，同时也为阅读HELP方便，BEAM189的截面信息中统一用栅格(cell)、栅点(section node)、角栅点(section coner node)、RST角栅点(RST section nodes)（只有这些RST角栅点才提供结果，也可说是结果角栅点）等名字。
1.获取截面信息编号与提取截面特性—基本信息
以图1所示的工字型截面悬臂梁为例，提取截面的各种信息。
主要利用*GET的SECP项命令提取截面的各种特性数据，利用SECPLOT命令图显截面栅格和栅点编号，利用SLIST命令列表显示截面信息编号和坐标数据，更详细的解释见命令流中。主要信息如图2和图3所示。
2.提取常规的单元结果--杆件级
在单元HELP的输出列表中给出如图4所示的项目及其序号，现在来看表前半部分的提取方法。采用单元表ETABLE定义可定义这些结果项，然后通过单元表提取结果。如：“ETABLE,MYI,SMISC,2$ETABLE,MYJ,SMISC,15$PLLS,MYI,MYJ”绘制MY云图（图5）等。这种通过单元表提取常规结果的方法，大家都比较熟悉，这里从略。
3.截面的结果数据-像实体单元那样绘制结果云图并提取—截面级
在当前版本中，可打开单元形状，依据依据单元坐标系，采用PLNSOL命令或PLESOL命令绘制应力、应变等各种云图，如图6所示，但这种应力不能采用单元表提取，也不能像实体单元那样直接提取节点的应力结果。但可采用*GET命令的SECR提取几乎所有结果，如应力、应变及其组合等。
如提取第1个单元的最大SX的命令为：*GET,E1SXMA,SECR,1,S,X,MAX，更详细的见命令流中。
4.截面栅格和栅点的结果提取—截面点级
选取悬臂根部的单元，打开单元形状和应力值开关，绘制SX应力云图如图7所示。图7(a)中给出了单元的结果云图，并给出两个截面上某些部位的结果数值，这些结果数值的提取就涉及栅格和栅点结果（图4表中的下半部分CI、DI、EI、AI、BI等项）。
CI和CJ中的I和J分别表示单元I节点截面和J节点截面，CI和CJ表示RST角栅点结果（均值）；而DI和DJ表示截面积分点的结果（非平均）；更多的如AI、BI、EI等详见HELP。CI和CJ数值如下：
CI=(NN-1)*3 COMP
CJ=(NNMAX NN-1)*3 COMP
其中NN为RST角栅点编号（图3(d)），NNMAX为RST角栅点总数（本例为18），COMP应力或应变分量方向，如COMP=1表是XX，COMP=2表示XY，COMP=3表示XZ等。
对于给定的RST角栅点编号，如NN=15（图1中的C点），表示I和J截面的XX向数值时CI和CJ分别为：
CI=(15-1)*3 1=43，CJ=(18 15-1)*3 1=97，然后定义单元表和绘制云图命令如下：
ETABLE,N15SXI,LS,43
ETABLE,N15SXI,LS,97
PLLS,N15SXI,N15SXJ
选取一个单元和所有单元的第15号RST角栅点SX云图如图7(b)和图7(c)。提取数据可采用单元表的结果的提取方法（需要获知是第几个单元表），或者在提取单元结果中引用单元表名方法（推荐，不宜错）。
采用DO循环和数组可以提取所有单元的所有角栅点的所有结果项，保存在数组并输出到文件。梁截面栅格和栅点的结果，已经接近实体单元的结果项目，大大丰富了梁单元结果输出。
5.非线性或时程分析时ESOL提取结果
当存在多个结果点时，如非线性静力分析或动力分析等，可以采用ESOL命令（高版本提供）定义与单元表相关的命令项，如此一来则很容易获得截面、或某个角栅点的结果时程。与单元表相关的有SMISC、NMISC、LS、LEPEL、LEPTH、LEPPL、LEPCR、LBFE等命令项。
如定义单元1的第15号角栅点的SX为变量3，命令为“ESOL,3,1,,LS,43”，更详见的用法见命令流中。通过所定义的变量输出到文件就比较简单了，也就是提取了这些结果。
!===============================
!悬臂工字梁的BEAM189计算结果输出
FINISH$/CLEAR$/PREP7
ET,1,BEAM189,,,,2
MP,EX,1,2.1E5$MP,PRXY,1,0.3
SECTYPE,1,BEAM,I
SECDATA,200,200,300,16,16,12
!1==========================
!图显截面和截面特性
SECPLOT,1!如图2所示
!命令提取截面信息
*GET,AREA1,SECP,1,PROP,AREA
*GET,IYY1,SECP,1,PROP,IYY
*GET,IYZ1,SECP,1,PROP,IYZ
*GET,IZZ1,SECP,1,PROP,IZZ
*GET,WARP1,SECP,1,PROP,WARP
*GET,TORS1,SECP,1,PROP,TORS
*GET,CGY1,SECP,1,PROP,CGY
*GET,CGZ1,SECP,1,PROP,CGZ
*GET,SHCY1,SECP,1,PROP,SHCY
*GET,SHCZ1,SECP,1,PROP,SHCZ
*GET,SCYY1,SECP,1,PROP,SCYY
*GET,SCYZ1,SECP,1,PROP,SCYZ
*GET,SCZZ1,SECP,1,PROP,SCZZ
*STAT
!图显截面信息编号(如图3所示)
!SECPLOT,SECID,MESHKEY
SECPLOT,1,0!不显示删格
SECPLOT,1,1!显示删格
SECPLOT,1,2!带角删点编号显示删格
SECPLOT,1,3!带删格编号显示删格
SECPLOT,1,4!带材料号和颜色显示删格
SECPLOT,1,5!仅带料号颜色显示删格
SECPLOT,1,6!带"RST角删点编号"显示删格(实质上是截面角删点次序编号)
SECPLOT,1,7!带"RST删格编号"显示删格(与3相同)
!MESHKEY=2-7命令项在V10中没有，且MESHKEY=2-7时无质心和剪心信息，也无截面特性信息
!列表显示截面特性数据、删格编号、删点坐标、积分点坐标等信息
SLIST,1,,,FULL!
L=2000$K,1$K,2,L
K,10,L/2,L/2$L,1,2
LATT,1,1,1,,,10,1
LESIZE,ALL,,,20
LMESH,ALL$DK,1,ALL
FK,2,FY,-5E4$FK,2,FZ,-2E4
SAVE,GZL,DB
/SOLU$SOLVE$/POST1
/ESHAPE,1$PLNSOL,U,SUM
/DSCALE,,OFF
!2=========================
!定义单元表，提取结果项(图5)
ETABLE,MYI,SMISC,2
ETABLE,MYJ,SMISC,15
PLLS,MYI,MYJ
ETABLE,MZI,SMISC,3
ETABLE,MZJ,SMISC,16
PLLS,MZI,MZJ
!提取单元1的MYI和MYJ
*GET,MY10,ETAB,1,ELEM,1
*GET,MZ10,ETAB,3,ELEM,1
!3=========================
!绘制应力等云图(图6)
PLNSOL,S,X$PLNSOL,S,XY
PLNSOL,S,XZ$PLNSOL,S,1
!提取截面应力应变等结果
!提取单元1的SX最大最小
*GET,E1SXMA,SECR,1,S,X,MAX
*GET,E1SXMN,SECR,1,S,X,MIN
!提取单元1的SXZ最大
*GET,E1SXY,SECR,1,S,XZ,MAX
!4========================
!绘制单元1的应力云图
ESEL,S,,,1$/PNUM,SVAL,1
PLNSOL,S,X!图7(a)
!给定RST角栅点编号，如15
!截面RST角栅点总数为18
ALLSEL,ALL
NN=15$NNMAX=18
CI1=(NN-1)*3 1
CJ1=(NNMAX NN-1)*3 1
ETABLE,N15SXI,LS,CI1
ETABLE,N15SXJ,LS,CJ1
PLLS,N15SXI,N15SXJ!图7(c)
PRETAB,N15SXI,N15SXJ
!类似的看该点的弹性应变
ETABLE,N15EXI,LEPEL,CI1
ETABLE,N15EXJ,LEPEL,CJ1
PLLS,N15EXI,N15EXJ
!提取单元1的上述应力数值
ETABLE,STAT!查看ETAB状态
!N15SXI为第5个ETAB
*GET,E1N15SXI,ETAB,5,ELEM,1
!也可用ETAB名提取
*GET,E1N15S,ELEM,1,ETAB,N15SXI
!5=========================
!如是非线性或时程分析时
FINISH$RESUME,GZL,DB
/SOLU$NLGEOM,ON
OUTRES,ALL,ALL
NSUBST,20$SOLVE
/POST26
NSOL,2,2,U,Y$PLVAR,2
!定义单元1的第15号角栅点的SX为变量3
!前述计算中CI1=43
ESOL,3,1,,LS,43$PLVAR,3
!定义单元2的第7号角栅点的EPEL-x为变量4
!注意ESOL这里不认变量名
CC2=(7-1)*3 1
ESOL,4,2,,LEPEL,%CC2%$PLVAR,4
!定义单元1的I节点MY为变量5
ESOL,5,1,,SMISC,2$PLVAR,5
总之，高版本的BEAM189的计算结果十分丰富，除了欧拉梁的常规计算结果之外，还提供了截面、栅格和栅点的计算结果，可以说已经接近实体单元的各项计算结果。文中给出了各种计算结果的云图显示和列表显示，同时给出了这些结果的采用命令流的提取方法，可减少人工工作，大大提高了结果提取效率
声明：原创文章，欢迎留言与我讨论，如需转载留言
