ANSYS在梁壳体单元中的独立网格布筋法，性能优良
如前文的REINF264（ANSYS离散加强筋单元REINF264，模拟加筋新途径之一）和REINF265单元（ANSYS弥散加强筋单元REINF265，模拟加筋新途径之二），用于在基材中加筋或加膜形成加强筋或加强膜，与基材相互作用从而提高基材承载力。本文介绍在基材中的布筋方法，即在基材单元中布置加强筋单元或加强膜单元。
1.加强筋单元概要
基本假定：加强筋横截面尺寸与其长度相比很小，在结构分析中忽略其弯曲、扭转和剪切刚度，只考虑其轴向刚度；加强膜则考虑平面上的两个刚度。加强筋与基材完全连接，二者变形协调，即不能考虑二者的相对滑移。
筋材形式：加强筋有两种布置形式，分别为离散加强筋（SECTYPE,SECID,REINF,DISC）和弥散加强筋（SECTYPE,SECID,REINF,SMEAR）。实际上根本不用关心是REINF263、REINF264或是REINF265单元，因为不能直接通过定义节点创建加强筋单元，加强筋单元由程序自动生成，程序会根据加强筋具体情况自动生成相应的单元。
布筋方法：指创建加强筋（或加强膜）并在基材单元中生成加强筋单元的方法，有独立网格布筋法（Mesh-independent method）和标准布筋法（Standard method），无论采用哪种布置形式（离散或弥散），两种布筋方法均可使用。
2.独立网格布筋法
所谓独立网格布筋法是指独立创建基材几何模型，然后独立划分单元网格，不考虑筋材。然后独立创建筋材模型，通过加强筋截面SECTYPE和SECDATA定义材料、横截面、间距和方向等，并划分筋材为MESH200单元以确定加强筋位置。最后，选择基材单元和MESH200单元，生成加强筋单元（程序自动生成REINF26x，这个也不必关心）。独立网格布筋法步骤如下：
1）创建基材模型并划分基材单元。与传统方法相同，不再赘述。
2）创建具有加强筋特性的几何模型并划分为MESH200单元。初始状态可通过MESH200定义(命令INISTATE)，且仅支持基于节点的初始状态定义，且仅仅独立网格法才能使用。
3）选择基材单元和对应的MESH200单元。
4）生成加强筋单元(命令EREINF)
5）检查。
例1.设一矩形截面梁0.2m×0.3m×2m，在其下缘布置2根φ20mm的钢筋，中心边距均为40mm。上缘均匀分布3根φ10mm钢筋，中心边距35mm。下面分别采用SOLID185和BEAM189模拟梁体，并分别采用离散和弥散方式布置钢筋，命令流如下。
!SOLID185-独立网格布筋法-离散
FINISH$/CLEAR$/PREP7
LB=0.2$LH=0.3$LL=2.0
BJ=0.04$BJ1=0.03
ET,1,SOLID185!8节点实体单元
ET,2,MESH200,2!2节点3D线元
ET,3,MESH200,2!2节点3D线元
MP,EX,1,3E10!基材弹性模量
MP,PRXY,1,0.2
MP,EX,2,2.1E11!筋材弹性模量
MP,PRXY,2,0.3
!创建基材模型并划分单元==========
BLC4,,,LL,LH,LB
ESIZE,0.05$MSHKEY,1$
VATT,1,,1$VMESH,ALL
!定义离散筋材参数(两种截面)--
AG20=ACOS(-1)/4*20*20*1E-6
AG10=ACOS(-1)/4*10*10*1E-6
SECTYPE,2,REINF,DISC
SECDATA,2,AG20,MESH
SECTYPE,3,REINF,DISC
SECDATA,2,AG10,MESH
!下缘布筋---------------------
!创建线并划分MESH200单元------
LSEL,NONE
K,1001,0,BJ,BJ$K,1002,LL,BJ,BJ
L,1001,1002
LGEN,2,ALL,,,0,0,LB-2*BJ
LATT,,,2,,,,2$LESIZE,ALL,,,1
LMESH,ALL
!选择单元，生成下缘加筋单元---
ESEL,S,TYPE,,1$ESEL,A,TYPE,,2
EREINF!下缘布筋完毕
!上缘布筋---------------------
!创建线并划分MESH200单元!-----
LSEL,NONE!!
K,2001,0,LH-BJ1,BJ1
K,2002,LL,LH-BJ1,BJ1
L,2001,2002
LGEN,3,ALL,,,0,0,(LB-2*BJ1)/2
LATT,,,3,,,,3$LESIZE,ALL,,,1
LMESH,ALL!
!选择单元，生成上缘加筋单元---
ESEL,S,TYPE,,1$ESEL,A,TYPE,,3
EREINF!上缘布筋完毕
!加筋单元云图-----------------
ESEL,S,TYPE,,1
/TRLCY,ELEM,0.9$ESEL,ALL
/ESHAPE,1
EPLOT!图1
!*********************************
!SOLID185-独立网格布筋法-弥散
FINISH$/CLEAR$/PREP7$LB=0.2
LH=0.3$LL=2.0
BJ=0.04$BJ1=0.03!!
ET,1,SOLID185 !8节点实体单元
ET,2,MESH200,6 !4节点3D面
ET,3,MESH200,6 !4节点3D面
MP,EX,1,3E10 !基材弹性模量
MP,PRXY,1,0.2!
MP,EX,2,2.1E11!筋材弹性模量!
MP,PRXY,2,0.3!!
!创建基材模型并划分185单元=======
BLC4,,,LL,LH,LB!
ESIZE,0.05$MSHKEY,1
VATT,1,,1$VMESH,ALL!
!定义弥散筋材参数-------------
!3根Φ10MM筋材宽度上均匀分布
!2根Φ20MM筋材宽度上均匀分布
LOCAL,12!先定义局部坐标系
AG10=ACOS(-1)/4*10.*10*1E-6
AG20=ACOS(-1)/4*20*20*1E-6!
SECTYPE,2,REINF,SMEAR
SECDATA,2,3*AG10,LB,12,0,MESH
SECTYPE,3,REINF,SMEAR
SECDATA,2,2*AG20,LB,12,0,MESH
!创建上层MESH200单元(面单元)--
ASEL,S,LOC,Y,LH
AGEN,2,ALL,,,0,-BJ1
*GET,A1,AREA,,NUM,MAX
ASEL,S,,,A1$AATT,,,2,,2
ESIZE,LL$AMESH,ALL
!选择单元，生成上层加筋单元---
ESEL,S,TYPE,,1$ESEL,A,TYPE,,2!!
EREINF!完成上层布筋
!创建下层MESH200单元(面单元)--
ASEL,S,LOC,Y,0
AGEN,2,ALL,,,0,BJ
*GET,A1,AREA,,NUM,MAX!
ASEL,S,,,A1$AATT,,,3,,3
ESIZE,LL$AMESH,ALL!!
!选择单元，生成下层加筋单元---
ESEL,S,TYPE,,1!
ESEL,A,TYPE,,3
EREINF!完成下层布筋
!加筋单元云图--------------
ESEL,S,TYPE,,1!!!
/TRLCY,ELEM,0.81$ESEL,ALL
/ESHAPE,1$EPLOT
!检查弥散加筋X方向
ESEL,S,TYPE,,4
/DEVICE,VECTOR,1
/ESHAPE,0
/PSYMB,LAYR,-1
EPLOT!图2
!BEAM189-独立网格布筋法-离散
!是否支持3节点待考版本
FINISH$/CLEAR
/PREP7
LB=0.2$LH=0.3$LL=2.0!
BJ=0.04$BJ1=0.03!!!
ET,1,BEAM189!3节点梁单元
ET,2,MESH200,3!3节点3D线元
MP,EX,1,3E10 !基材弹性模量!
MP,PRXY,1,0.2!!
MP,EX,2,2.1E11!筋材弹性模量!!
MP,PRXY,2,0.3!!!
!创建基材BEAM模型================
SECTYPE,1,BEAM,RECT
SECDATA,LB,LH
K,1$K,2,LL$K,3,LL/2,1
L,1,2$LATT,1,,1,,,3,1
ESIZE,0.1$LMESH,ALL
!独立网格布筋法(仅能离散)========
!定义离散筋材参数-------------
AG20=ACOS(-1)/4*20.*20*1E-6!
AG10=ACOS(-1)/4*10.*10.*1E-6!!
SECTYPE,2,REINF,DISC!
SECDATA,2,AG20,MESH!!!
SECTYPE,3,REINF,DISC!!!
SECDATA,2,AG10,MESH!!!
!创建下缘MESH200单元(2D线)----
LSEL,NONE!!!
K,1001,0,-LH/2 BJ,-LB/2 BJ
K,1002,LL,-LH/2 BJ,-LB/2 BJ
L,1001,1002!
LGEN,2,ALL,,,0,0,LB-2*BJ!!
LATT,,,2,,,,2$LESIZE,ALL,,,1!!
LMESH,ALL!!!
!创建上缘MESH200单元(2D线)!---
LSEL,NONE!!!!
K,2001,0,LH/2-BJ1,-LB/2 BJ1
K,2002,LL,LH/2-BJ1,-LB/2 BJ1
L,2001,2002!!!
LGEN,3,ALL,,,0,0,(LB-2*BJ1)/2!
LATT,,,2,,,,3$LESIZE,ALL,,,1
LMESH,ALL!!!!
!选择单元，生成所有加筋单元---
ESEL,S,TYPE,,1$ESEL,A,TYPE,,2!
EREINF!完成布筋
!加筋单元云图--------
ESEL,S,TYPE,,1!!
/TRLCY,ELEM,0.91$ESEL,ALL
/ESHAPE,1$EPLOT!图3
例2.一圆柱壳如图4所示，布筋命令流如下。
!SHELL181-独立网格布筋法-离散
!为方便显示采用1/4模型
FINISH$/CLEAR$/PREP7!!
R0=1.0$H0=0.3$LH=2.0
ZJBH=0.05$GJJJ=0.1
ET,1,SHELL181!4节点壳单元
ET,2,MESH200,2 !2节点3D线元
MP,EX,1,3E10!基材弹性模量!!
MP,PRXY,1,0.2!!!
MP,EX,2,2.1E11!筋材弹性模量!!!
MP,PRXY,2,0.30!!!
MP,EX,3,2.06E11!筋材弹性模量
MP,PRXY,3,0.3!仅为显示
!创建基材SHELL模型===============
SECTYPE,1,SHELL$SECDATA,H0
K,1,R0-H0/2$K,2,R0-H0/2,,LH
K,3$K,4,,,LH$L,1,2
AROTAT,1,,,,,,3,4,90
AATT,1,,1,,1$ESIZE,0.04$AMESH,ALL
!定义离散筋材参数----------
AG20=ACOS(-1)/4*20*20*1E-6!!!
AG6=ACOS(-1)/4*6*6*1E-6!!!
SECTYPE,2,REINF,DISC!!!!
SECDATA,2,AG20,MESH!!!!
SECTYPE,3,REINF,DISC!!!!
SECDATA,3,AG6,MESH
!创建主筋MESH200单元(2D线)----
LSEL,NONE!!!!!
K,1001,R0-H0 ZJBH,0,0
K,1002,R0-H0 ZJBH,0,LH
L,1001,1002!!
LGEN,2,ALL,,,H0-2*ZJBH
CSYS,1$LGEN,7,ALL,,,0,15
LATT,,,2,,,,2$LESIZE,ALL,,,1!!!
LMESH,ALL!-!!!
!创建箍筋MESH200单元(2D线)----
LSEL,NONE$CSYS,1
K,2001,R0-H0 ZJBH
K,2002,R0-H0 ZJBH,90
K,2003,R0-ZJBH
K,2004,R0-ZJBH,90
L,2001,2002$L,2003,2004
CSYS,0
LGEN,1,ALL,,,0,0,GJJJ,,,1
LGEN,19,ALL,,,0,0,GJJJ
LATT,,,2,,,,3
ESIZE,0.10$LMESH,ALL
!选择单元，生成所有加筋单元--
ESEL,S,TYPE,,1!!--!
ESEL,A,TYPE,,2!!!
EREINF!
!加筋单元云图!-----------------
ESEL,S,TYPE,,1!!!!
/TRLCY,ELEM,0.92$ESEL,ALL
/ESHAPE,1$EPLOT!图4
特别是使用时要注意（因破解版本众多，有些功能需验检）以下问题：
1.是否支持所用基材单元中布筋？不是所有单元都支持布筋，需要查阅HELP。
2.基材单元是否支持高阶单元布筋？如SOLID186在低版本中不支持。
3.基材单元支持何种布筋方式（离散或弥散）？如BEAM189仅支持离散方式。
4.准加强筋位置是否在单元截面（BEAM或SHELL）或单元体之外？当准加强筋在其之外时则不生成加强筋单元，只有在其内部的才生成加强筋单元。
5.梁或壳厚度方向不能布筋。
6.当梁或壳体单元叠合时（打开单元形状），是否能够生成加强筋单元？低版本则不可以。
7.加强筋单元（打开单元形状）显示是否正常？低版本存在这种问题。
8.标准布筋法和独立网格布筋法可同时使用，但一定要注意检查是否正确。
9.离散方式和弥散方式也可同时使用，即REINF264和REINF265可同时存在。
10.加强筋单元与基材单元完全变形协调，因基材变形连续，加强筋亦然。因此当基材连续，而筋材断开时模拟可能是个问题。
声明：原创文章，欢迎留言与我讨论，如需转载留言
