ANSYS弥散加强筋单元REINF265，模拟加筋新途径之二
单元REINF264为离散加强筋单元，REINF265为弥散加强筋单元，以实体单元（SOLID和SHELL）为基材单元，为模拟加筋或加层途径之二。
1.REINF265单元描述
该单元采用弥散方法（smeared approach）布置加强筋（加强膜），以层形式模拟均匀分布的加强筋，每层加强筋都具有方向、材料属性和横截面。REINF265除可模拟仅有轴向刚度的加强筋（与REINF264功能相同）外，还可模拟加强膜（平面应力状态，高版本中才有）。如图1为加强筋与其基材单元（图中蓝色的单元名称）描述及其自身单元坐标系。
采用命令SECTYPE和SECDATA定义加强筋单元的材料号、截面积、间距、位置和方向信息等，当然采用命令EREINF创建REINF265单元很容易。
层等效厚度通过单根加强筋面积/加强筋间距计算。当模拟加强膜时，则忽略加强筋间距（令其等于1.0），此时层等效厚度就等于单根加强筋横截面面积。
命令“SECCONTROL,,,MEMOPT”用于定义加强筋（单轴应力状态，此为默认），还是加强膜（平面应力状态）。
层坐标系可以通过LOCAL定义局部坐标系，然后在SECDATA中输入坐标系号确定，推荐使用此方法。
加强筋仅拉、仅压行为可通过SECCONTROL命令设置，但加强膜不可设置仅拉或压。
对结构分析而言，加强筋单元REINF265无单元荷载，其温度荷载与基材单元相同。
REINF265单元初始状态可采用命令INISTATE设置，也可使用独立网格法将MESH200的特性转换过来。
REINF265单元无需实常数，正常的材料弹性参数用MP定义，而所支持的材料模型用TB定义。该单元支持单元生死、大挠度、大应变、应力刚化、线性摄动分析等。单元输出可参见HELP。
应用时注意REINF264单元必须有基材单元；不能在壳单元或分层实体单元厚度方向设置加强筋；仅拉/压打开时为非线性分析。
2.REINF265在SOLID185中的应用
前文中（ANSYS之DPC模型的钢筋混凝土周边简支板极限承载力分析）,这里采用SOLID185 REINF265进行计算，命令流和结果如下。
FINISH$/CLEAR$/PREP7
!几何参数定义
PL=6!板长度
PB=4!板宽度
PD=0.2!板厚度
PBH=0.03!钢筋保护层(中)
!混凝土材料参数-C30混凝土=========
EC=3.0E10!混凝土弹性模量
BOS=0.2!泊松系数
MP,EX,1,EC
MP,PRXY,1,BOS
!采用混凝土标准强度
RC=20.1E6!单轴抗压强度
RT=2.01E6!单轴抗拉强度
RB=1.2*RC!双轴抗压强度
DETC=1.0!压缩剪胀系数
DETT=0.25!拉伸剪胀系数
TB,CONCR,1,,,DP
TBDATA,1,RC,RT,RB
TB,CONCR,1,,,DILA
TBDATA,1,DETT,DETC
TB,CONCR,1,,,RCUT
TBDATA,1,RT
!采用HSD2-----------------
OCI=0.3!开始硬化时相对应力
OCU=0.85!与KCU对应的相对应力
OCR=0.25!剩余压缩相对应力
KCM=0.00164!强度峰值点应变
KCU=0.003772!变点应变
OTR=0.15!剩余拉伸相对应力
GFT=115!拉伸比面积断裂能
TB,CONCR,1,,,HSD2
TBDATA,1,KCM,KCU,OCI,OCU,OCR
TBDATA,6,GFT,OTR
!钢筋材料参数=====================
!设采用HRB400钢筋
MP,EX,2,2.1E11!钢筋弹性模量
MP,PRXY,2,0.3
TB,BKIN,2!双线性随动强化模型
TBDATA,1,400E6,1600E6
!创建模型=========================
ET,1,SOLID185,,3
ET,2,MESH200,6
ET,3,MESH200,6
!创建体并划分SOLID185网格---------
BLOCK,0,PL/2,-PD,0,0,PB/2
LSEL,S,LOC,X,PL/4
LSEL,A,LOC,Z,PB/4
LESIZE,ALL,,,30
LSEL,INVE$LESIZE,ALL,,,4
LSEL,ALL$VATT,1,1,1
MSHKEY,1$VMESH,ALL
ESEL,A,CENT,Y,-PD,-3*PD/4
CM,BJ185,ELEM
!直径为6MM的钢筋面积----------
AG6=ACOS(-1)/4*6E-3*6E-3
DX=0.245!钢筋X向间距
DZ=0.15!钢筋Z向间距
!先设置与X方向平行的钢筋MESH200===
WPCSYS,-1
WPROTA,,90
CSWPLA,12
CSYS,0
SECTYPE,2,REINF,SMEAR
SECDATA,2,AG6,DZ,12,0,MESH
ASEL,S,LOC,Y,-PD
AOFFST,ALL,-PBH
*GET,MYA2,AREA,,NUM,MAX
ASEL,S,,,MYA2
ESIZE,1
AATT,2,,2,12,2
AMESH,ALL
!设置与Z方向平行的钢筋MESH200===
SECTYPE,3,REINF,SMEAR
SECDATA,2,AG6,DX,12,90,MESH
ASEL,S,LOC,Y,-PD!
AOFFST,ALL,-PBH!
*GET,MYA3,AREA,,NUM,MAX
ASEL,S,,,MYA3$ESIZE,1
AATT,2,,3,12,3$AMESH,ALL
!生成钢筋REFIN265=================
!与X方向平行的钢筋
ESEL,S,TYPE,,2
CMSEL,A,BJ185
EREINF
CMSEL,U,BJ185
ESEL,U,TYPE,,2
CM,GJ1Z,ELEM
!与Z方向平行的钢筋
ESEL,S,TYPE,,3
CMSEL,A,BJ185!
EREINF!
CMSEL,U,BJ185!
ESEL,U,TYPE,,3
CM,GJ2X,ELEM
ALLSEL,ALL
!修改边界上的混凝土单元为弹性单元
MP,EX,3,EC
MP,PRXY,3,BOS
MP,DENS,3,CDEN
NSEL,S,LOC,X,PL/2
NSEL,A,LOC,Z,PB/2
ESLN
ESEL,R,ENAME,,SOLID185
EMODIF,ALL,MAT,3$ALLSEL,ALL
!施加边界条件====================
!竖向约束
NSEL,S,LOC,X,PL/2!
NSEL,R,LOC,Y,-PD$D,ALL,UY
NSEL,S,LOC,Z,PB/2
NSEL,R,LOC,Y,-PD$D,ALL,UY!!
!对称约束
NSEL,S,LOC,X$D,ALL,UX
NSEL,S,LOC,Z$D,ALL,UZ
ALLSEL,ALL!!
DDELE,NODE(PL/2,-PD,PB/2),ALL
!施加荷载求解==================
/SOLU
AUTOTS,ON$OUTRES,ALL,ALL
ERESX,NO$P0=30E3$TIME,1
NSEL,S,LOC,Y
SF,ALL,PRES,P0$NSEL,ALL
NSUBST,100,,30
SOLVE
/POST26
N1=NODE(0,-PD,0)
NSOL,2,N1,U,Y
PROD,3,2,,,,,,-1000
PROD,4,1,,,,,,P0/1000
XVAR,3$PLVAR,4
同样是通过MESH200创建加强筋单元，REINF264可清晰看出加强筋布置情况，而REINF265则需要命令”/PSYMB,LAYR,-1”显示加强筋单元x轴向。
声明：原创文章，欢迎留言与我讨论，如需转载留言
