ANSYS离散加强筋单元REINF264，模拟加筋新途径之一
想玩玩REINF263/264/265单元，但没有搜索到这几个单元的中文介绍。因此，花点时间把REINF264/265这两个单元先介绍一下，以便应用。
在ANSYS的HELP中REINF264名称为“3-D Discrete Reinforcing”，其意思不难理解，根据其应用场景，称之为“加强筋”较为合适，此加强筋可为混凝土中的钢筋、复合材料中的纤维（碳纤维、玻璃纤维、芳纶纤维等）、轮胎中的尼龙线、土墙中的竹条等等。
加强筋单元有REINF263、REINF264、REINF265三种，REINF263为2D弥散加强筋单元，REINF264为3D离散加强筋单元，REINF265为3D弥散加强筋（还可做加强膜）单元，考虑到应用情况，这里仅简单介绍REINF264和REINF265单元（另文）。
1.REINF264单元描述
该单元可以模拟任意方向的加强筋，且仅有轴向刚度，如图1为加强筋与其基材单元（图中蓝色的单元名称）描述及其自身单元坐标系。
REINF264单元与其基材单元共用节点，但用REINF264与基材单元的交点表示（如II、JJ或II、JJ、KK），因此REINF264单元坐标系由II、JJ确定，与基材单元的单元坐标系（/PSYMB,ESYS查看）无关。
特别地，REINF264/265不能通过定义节点创建单元，只能通过另外方法（独立网格布筋法或标准布筋法）创建。
采用命令SECTYPE和SECDATA定义加强筋单元的材料号、截面积和位置信息等。
采用命令EREINF在选择的基材单元中生成加强筋单元。
加强筋单元REINF264可仅拉、仅压或拉压，采用命令SECCONTROL设置。
对结构分析而言，加强筋单元REINF264无单元荷载，其温度荷载与基材单元相同。
REINF264单元初始状态可采用命令INISTATE设置，也可使用独立网格法将MESH200的特性转换过来。
REINF264单元的节点和自由度与基材单元相同，如当基材单元为BEZM189时，则REINF264单元每个节点有6个自由度（3个平动 3个转动自由度），如基材单元为SOLID185时，则REINF264单元每个节点有3个平动自由度。
REINF264单元无需实常数，正常的材料弹性参数用MP定义，而所支持的材料模型用TB定义。该单元支持单元生死、大挠度、大应变、应力刚化、线性摄动分析等。
单元输出与LINK180类似，此处不再赘述（可参见HELP）。
应用时注意REINF264单元必须有基材单元；不能在壳单元或分层实体单元厚度方向设置加强筋；仅拉/压打开时为非线性分析；不支持BEAM188的二次插值设置等。
2.REINF264在BEAM189中的应用
设一箱型截面简支梁如图2a)所示，跨度为10m，受均布荷载作用，材料参数和几何尺寸命令流中。假定受拉区和受压区加强筋各有4根全梁布置，其余则仅在1.5~8.5m范围布置。
采用标准布筋法创建加强筋，且按弹性分析。
根据换算截面法可手工计算结果，与ANSYS计算的对应结果（图2各图），跨中上缘应力为9.267/9.24MPa(理论/ANSYS，下同)，跨中下缘应力为8.305/8.28MPa，跨中受压区加强筋应力为56.67/56.5MPa，跨中受拉区加强筋应力47.88/47.7MPa，跨中挠度则为10.169mm/ 10.529mm。因此可以确认REINF264在BEAM189中的应用是正确的。命令流如下，命令流中也可仅设置两种加强筋类型，即跨中部分为一种，而端部为另一种。
FINISH$/CLEAR$/PREP7
ET,1,BEAM189
MP,EX,1,3E10!基材单元材料
MP,PRXY,1,0.2
MP,EX,2,2.1E11!加强筋材料
MP,PRXY,2,0.3
SECTYPE,1,BEAM,HREC
SECDATA,0.8,0.6,0.1,0.1,0.15,0.15
!创建梁模型=======================
K,1$K,2,1.5$K,3,8.5$K,4,10
K,5,5,1$L,1,2$L,2,3$L,3,4
LATT,1,,1,,,5,1
ESIZE,1$LMESH,ALL
!定义加强筋(标准布筋法)===============
!设加强筋面积分别为:
AG30=ACOS(-1)/4*30*30*1E-6
AG20=ACOS(-1)/4*20*20*1E-6
!受压区短加强筋-------------------
!2号截面类型,加强筋,离散型
!材料号,面积,BEAM,Y1,Z1(截面原点)
SECTYPE,2,REINF,DISC
SECDATA,2,AG20,BEAM,0.20,0.56
SECDATA,2,AG20,BEAM,0.30,0.56
SECDATA,2,AG20,BEAM,0.40,0.56
SECDATA,2,AG20,BEAM,0.50,0.56
SECDATA,2,AG20,BEAM,0.60,0.56
!受压区通长加强筋-----------------
!3号截面类型,加强筋,离散型
!材号,面积,BEAM,Y1,Z1(截面原点)
SECTYPE,3,REINF,DISC
SECDATA,2,AG20,BEAM,0.02,0.56
SECDATA,2,AG20,BEAM,0.10,0.56
SECDATA,2,AG20,BEAM,0.70,0.56
SECDATA,2,AG20,BEAM,0.78,0.56
!受拉区短加强筋-------------------
!4号截面类型,加强筋,离散型
!材料号,面积,BEAM,Y1,Z1
SECTYPE,4,REINF,DISC
SECDATA,2,AG30,BEAM,0.20,0.05
SECDATA,2,AG30,BEAM,0.30,0.05
SECDATA,2,AG30,BEAM,0.40,0.05
SECDATA,2,AG30,BEAM,0.50,0.05
SECDATA,2,AG30,BEAM,0.60,0.05
!受拉区通长加强筋-----------------
!5号截面类型,加强筋,离散型
!材料号,面积,BEAM,Y1,Z1!
SECTYPE,5,REINF,DISC
SECDATA,2,AG30,BEAM,0.03,0.05
SECDATA,2,AG30,BEAM,0.10,0.05
SECDATA,2,AG30,BEAM,0.70,0.05
SECDATA,2,AG30,BEAM,0.77,0.05
!短加强筋设置-------------
ESEL,S,CENT,X,1.5,8.5
SECNUM,2$EREINF
SECNUM,4$EREINF
!长加强筋设置-------------
ESEL,ALL
SECNUM,3$EREINF
SECNUM,5$EREINF$EPLOT!图2B)
/ESHAPE,1$ESEL,S,TYPE,,1
/TRLCY,ELEM,0.9
ESEL,ALL$EPLOT!图2C)
ESEL,S,SEC,,1$ESEL,A,SEC,,4,5
EPLOT!图2D)受拉区加强筋
ESEL,S,SEC,,1,3$EPLOT!图2E)压区
ALLSEL,ALL
/SOLU
DK,1,UX,,,,UY,UZ,ROTX
DK,4,UY,,,,UZ
SFBEAM,ALL,1,PRES,40000
SOLVE
/POST1$/TRLCY,ELEM,0
ESEL,S,TYPE,,1
PLNSOL,U,Y!图2F)变形云图
PLNSOL,S,X
ESEL,S,SEC,,2,5
PLNSOL,S,X!图2G)加强筋应力
3.REINF264在SOLID185中的应用
在SOLID单元和SHELL单元中，采用标准布筋法创建REINF264单元不够方便，除非基材单元很规则且加强筋数目很少，因此在实体单元中多用独立网格布筋法。独立网格布筋法类似《ANSYS工程结构数值分析》中的约束方程法，即基材单元和加强筋各自独立划分网格，然后通过命令EREINF将MESH200转换为REINF264单元。
采用上述简支梁的例子，先创建实体梁模型(SOLID185)；然后独立创建线-生成MESH200；最后用EREINF命令生成加强筋单元。命令流如下，部分结果如图3所示。
FINISH$/CLEAR$/PREP7!
ET,1,SOLID185
MP,EX,1,3E10!基材单元材料!
MP,PRXY,1,0.2!
MP,EX,2,2.1E11!加强筋材料!
MP,PRXY,2,0.3!
!创建实体模型==================
WPROTA,,,90
BLC4,,,-0.8,0.6,10
BLC4,-0.1,0.15,-0.6,0.3,10
VSBV,1,2
WPOFF,,,1.5$VSBW,ALL
WPOFF,,,7.0$VSBW,ALL
WPCSYS,-1$WPOFF,,,0.1$VSBW,ALL
WPOFF,,,0.6$VSBW,ALL
WPROTA,,-90
WPOFF,,,0.15$VSBW,ALL
WPOFF,,,0.30$VSBW,ALL
WPCSYS,-1$MSHKEY,1
LSEL,S,TAN1,X$LSEL,R,LOC,Z,0
LESIZE,ALL,,,2
LSEL,S,TAN1,X$LSEL,R,LOC,Y,0
LSEL,U,LOC,Z,0.1,0.5
LESIZE,ALL,,,2$ESIZE,0.15
ALLSEL,ALL$VATT,1,,1$VMESH,ALL
NUMCMP,ALL!压缩编号
!定义加强筋(独立网格布筋法)=======
!加强筋面积分别计算如下:
AG30=ACOS(-1)/4*30*30*1E-6!
AG20=ACOS(-1)/4*20*20*1E-6!
SECTYPE,2,REINF,DISC!
SECDATA,2,AG20,MESH
SECTYPE,3,REINF,DISC!
SECDATA,2,AG30,MESH
ET,2,MESH200,2
!创建受拉区加强筋-------
!可采用线复制，建模更方便
K,1001,0,0.05,0.03
K,1002,0,0.05,0.10
K,1003,1.5,0.05,0.20
K,1004,1.5,0.05,0.30
K,1005,1.5,0.05,0.40
K,1006,1.5,0.05,0.50
K,1007,1.5,0.05,0.60
K,1008,0,0.05,0.70
K,1009,0,0.05,0.77
K,1101,10.0,0.05,0.03
K,1102,10.0,0.05,0.10
K,1103,8.5,0.05,0.20
K,1104,8.5,0.05,0.30
K,1105,8.5,0.05,0.40
K,1106,8.5,0.05,0.50
K,1107,8.5,0.05,0.60
K,1108,10.0,0.05,0.70
K,1109,10.0,0.05,0.77
LSEL,NONE
*DO,I,1,9
L,1000 I,1100 I$*ENDDO
LESIZE,ALL,,,1$TYPE,2
SECNUM,3$LMESH,ALL
!创建受压区加强筋-------
LSEL,NONE!
K,2001,0,0.56,0.03
K,2002,0,0.56,0.10
K,2003,1.5,0.56,0.20
K,2004,1.5,0.56,0.30
K,2005,1.5,0.56,0.40
K,2006,1.5,0.56,0.50
K,2007,1.5,0.56,0.60
K,2008,0,0.56,0.70
K,2009,0,0.56,0.77
K,2101,10.0,0.56,0.03
K,2102,10.0,0.56,0.10
K,2103,8.5,0.56,0.20
K,2104,8.5,0.56,0.30
K,2105,8.5,0.56,0.40
K,2106,8.5,0.56,0.50
K,2107,8.5,0.56,0.60
K,2108,10.0,0.56,0.70
K,2109,10.0,0.56,0.77
LSEL,NONE!!
*DO,I,1,9,1
L,2000 I,2100 I$*ENDDO
LESIZE,ALL,,,1
TYPE,2$SECNUM,2$LMESH,ALL
!生成REINF264------------
ALLSEL,ALL$EREINF
!加强筋查看方法同上
!施加约束和荷载并求解=============
/SOLU$LSEL,S,LOC,Y,0
LSEL,R,LOC,X,0$DL,ALL,,UY
LSEL,S,LOC,Y,0!
LSEL,R,LOC,X,10$DL,ALL,,UY
ALLSEL,ALL!
DK,KP(0,0,0),UX,,,,UZ
DK,KP(10,0,0),UZ
ASEL,S,LOC,Y,0.6
SFA,ALL,1,PRES,40000/0.8
ASEL,ALL$SOLVE
/POST1$PLNSOL,U,Y
ESEL,S,TYPE,,1$PLNSOL,S,X
ESEL,S,TYPE,,3
/ESHAPE,1$PLNSOL,S,X
从较早版本的钢筋混凝土分离式模型角度看，采用REINF264十分方便。混凝土和钢筋均可独立创建几何模型，并独立划分网格（钢筋先用MESH200划分），然后采用命令EREINF完成钢筋布置。因此，无论多么复杂的钢筋布置（曲线或折线等），创建“线”几何模型还是很容易的。采用REINF264单元，不再切分体、节点耦合或约束方程等操作。当然，这种方法不能考虑钢筋和混凝土之间的粘结滑移。
声明：原创文章，欢迎留言与我讨论，如需转载留言
