钢筋混凝土偏心受压柱极限承载力分析，DPC和MWC模型比较
钢筋混凝土偏心受压柱如图1a)、b)所示，设混凝土采用C40，主筋采用HRB400，箍筋采用HRB335，材料参数详见命令流中。混凝土分别采用DPC模型和MWC两种模型，钢筋采用BKIN模型。
计算模型采用分离式模型，即混凝土采用SOLID185单元，钢筋采用LINK180单元。钢筋线切分体创建，即LINK180单元节点和SOLID185节点共共用，不考虑钢筋和混凝土简直的滑移。混凝土单元尺寸以50mm控制。同时将柱顶和柱底个一层单元采用弹性材料（与混凝土弹模相同），以防边界混凝土过早破坏而导致数值不收敛。单元如图1c)所示。
采用力加载（也可位移加载，位移加载可得到下降段），创建质量点和刚性区域加载。求解设置中，打开自动时间步，采用缺省的收敛准则。
FINISH$/CLEAR$/PREP7
!材料参数===========================
!C40混凝土(GB50010)
EC=3.25E10!混凝土弹性模量
BOS=0.2!泊松系数
CDEN=2350!混凝土密度(KG/M^3)
MP,EX,1,EC$MP,PRXY,1,BOS
MP,DENS,1,CDEN
!混凝土强度参数--------------
!采用混凝土强度标准值FCK和FTK
Rc=26.8E6!单轴抗压强度
Rt=2.39E6!单轴抗拉强度
Rb=1.2*Rc!双轴抗压强度
!剪胀系数或剪胀角------------
detc=1.0!压缩剪胀系数
dett=0.25!拉伸剪胀系数
PHI=31!内摩擦角
!HSD2定义混凝土本构关系------
Oci=0.33!开始硬化时相对应力
Ocu=0.5!与KCU对应的相对应力
Ocr=0.3!剩余受压相对应力
Kcm=0.00179!强度峰值点应变
Kcu=0.00358!变点应变
Otr=0.15!剩余拉伸相对应力
Gft=120!拉伸比面积断裂能(N/M)
!-----------------------------
MODNUM=1!模型选择与参数定义
!MODNUM=0仅DPC强度参数-------
*IF,MODNUM,EQ,0,THEN
TB,CONCR,1,,,DP
TBDATA,1,Rc,Rt,Rb
!MODNUM=1 DPC HSD2-----------
*ELSEIF,MODNUM,EQ,1
TB,CONCR,1,,,DP!
TBDATA,1,Rc,Rt,Rb!
TB,CONCR,1,,,DILA
TBDATA,1,dett,detc
TB,CONCR,1,,,HSD2
TBDATA,1,Kcm,Kcu,Oci,Ocu,Ocr
TBDATA,6,Gft,Otr
!MODNUM=2 DPC RANKINE无HSD2--
*ELSEIF,MODNUM,EQ,2
TB,CONCR,1,,,DP!!
TBDATA,1,Rc,Rt,Rb!!
TB,CONCR,1,,,DILA!
TBDATA,1,dett,detc!
TB,CONCR,1,,,RCUT
TBDATA,1,Rt
!MODNUM=3 DPC RANKINE HSD2---
*ELSEIF,MODNUM,EQ,3
TB,CONCR,1,,,DP!!!
TBDATA,1,Rc,Rt,Rb!!!
TB,CONCR,1,,,DILA!!
TBDATA,1,dett,detc!!
TB,CONCR,1,,,RCUT!!
TBDATA,1,Rt!!
TB,CONCR,1,,,HSD2!!
TBDATA,1,Kcm,Kcu,Oci,Ocu,Ocr!!
TBDATA,6,Gft,Otr!!
!MODNUM=4 MWC无HSD2----------
*ELSEIF,MODNUM,EQ,4
TB,CONCR,1,,,MW
TBDATA,1,Rc,Rt,Rb!!!!
TB,CONCR,1,,,DILA!!!!
TBDATA,1,PHI
!MODNUM=5 MWC HSD2-----------
*ELSEIF,MODNUM,EQ,5
TB,CONCR,1,,,MW!
TBDATA,1,Rc,Rt,Rb!!!!!
TB,CONCR,1,,,DILA!!!!!
TBDATA,1,PHI!!
TB,CONCR,1,,,HSD2!!!!!
TBDATA,1,Kcm,Kcu,Oci,Ocu,Ocr!!!!!
TBDATA,6,Gft,Otr!!!!!
*ELSE
!其余与0相同，即仅强度参数--
TB,CONCR,1,,,DP!!!!
TBDATA,1,Rc,Rt,Rb!!!!!!!!
*ENDIF
TBLIST
!钢筋材料参数-----------------
!设主筋采用HRB400钢筋
MP,EX,2,2.1E11!钢筋弹性模量
MP,PRXY,2,0.3
MP,DENS,2,7850
TB,BKIN,2!双线性随动强化模型
TBDATA,1,400E6,1700E6
!设箍筋采用HRB335钢筋
MP,EX,3,2.1E11!钢筋弹性模量
MP,PRXY,3,0.3
MP,DENS,3,7850
TB,BKIN,3!双线性随动强化模型
TBDATA,1,335E6,1600E6
!Φ20MM和Φ8MM钢筋面积
AG20=ACOS(-1)/4*20*20*1E-6
AG8=ACOS(-1)/4*8*8*1E-6
SECTYPE,2,LINK$SECDATA,AG20
SECTYPE,3,LINK$SECDATA,AG8
!边界处理材料
MP,EX,4,EC$MP,PRXY,4,BOS
MP,DENS,4,CDEN
!创建模型===========================
ZA=0.22!柱截面宽
ZB=0.32!柱截面长
ZG=1.2!柱高度
ZBH=0.04!主筋边距
ZJAJ=0.07!A向间距
ZJBJ=0.08!B向间距
KJJ=0.10!箍筋间距
BLC4,,,ZB,ZG,ZA
!切分体得到钢筋线
WPOFF,,,ZBH$VSBW,ALL
WPOFF,,,ZJAJ$VSBW,ALL
WPOFF,,,ZJAJ$VSBW,ALL!!
WPCSYS,-1$WPROTA,,,90
WPOFF,,,ZBH$VSBW,ALL!
*DO,I,1,3$WPOFF,,,ZJBJ
VSBW,ALL$*ENDDO
WPCSYS,-1$WPROTA,,-90
*DO,I,1,11$WPOFF,,,KJJ
VSBW,ALL$*ENDDO!!
WPCSYS,-1
!选择出主筋线和箍筋线
LSEL,S,LOC,X,ZBH,ZB-ZBH
LSEL,R,LOC,Z,ZBH,ZA-ZBH
CM,LS1,LINE
LSEL,U,LOC,X,ZBH
LSEL,U,LOC,X,ZB-ZBH
LSEL,U,LOC,Z,ZBH
LSEL,U,LOC,Z,ZA-ZBH
CM,LS2,LINE
CMSEL,S,LS1$CMSEL,U,LS2
LSEL,U,LOC,Y,0$LSEL,U,LOC,Y,ZG
CM,GJL,LINE
LSEL,U,TAN1,Y$CM,ZJ,LINE
CMSEL,S,GJL$CMSEL,U,ZJ
CM,KJ,LINE$ALLSEL,ALL
CMDELE,LS1$CMDELE,LS2
!定义单元并划分网格=================
ET,1,SOLID185,,3
ET,2,LINK180
ET,3,MASS21
R,4,0
VATT,1,,1$ESIZE,0.05
MSHKEY,1$VMESH,ALL
CMSEL,S,ZJ$LATT,2,,2,,,,2
LMESH,ALL
CMSEL,S,KJ$LATT,3,,2,,,,3
LMESH,ALL$ALLSEL,ALL
!上下顶面的单元改性
ESEL,S,CENT,Y,0.025
ESEL,A,CENT,Y,ZG-0.025
ESEL,R,ENAME,,SOLID185
EMODIF,ALL,MAT,4
ALLSEL,ALL
!施加边界条件=================
ASEL,S,LOC,Y,0
DA,ALL,UY
DK,KP(0,0,0),UX,,,,UZ
DK,KP(0,0,ZA),UX
ALLSEL,ALL!!
!创建质量单元施加荷载
*GET,NM,NODE,,NUM,MAX
NM0=NM 1
N,NM0,ZB/2,ZG,ZA/2
TYPE,3$REAL,4$E,NM0
NSEL,S,LOC,Y,ZG
CERIG,NM0,ALL,ALL$ALLSEL,ALL
!求解=========================
/SOLU
ANTYPE,0$OUTRES,ALL,ALL
AUTOTS,ON$ERESX,NO
TIME,1$NSUBST,1,,1
ACEL,,9.81$SOLVE
TIME,2$NSUBST,200,,50
P0=3000E3$PXJ=0.025
F,NM0,FY,-P0
F,NM0,MZ,-P0*PXJ
SOLVE
!时程后处理===================
/POST26
/GTHK,CURVE,1
/GMARKER,1,1,1
NSOL,2,NM,U,Y
PROD,3,1,,,,,,P0/1000
PROD,4,2,,,,,,-1000
XVAR,4
PLVAR,3
偏压柱几种组合情况的计算结果如图2所示，改为悬臂梁(修改加载)的结果如图3所示。通过计算分析可知：
1) DPC的仅强度参数（不考虑SHD时）与考虑HSD2时的结果有一定差别，且无HSD结果呈上限趋势。实际考虑HSD与否，需与试验结果对比确认。
2) 考虑SHD时，参数OCI越大，构件延性越低，但对极限承载力影响不大。其余参数，如过顶点后的OCU等参数影响较小。
3）收敛准则和荷载子步有一定影响，不能过度放松收敛准则，且荷载子步不宜过大（子步数不能太小）。
4）从MWC计算结果看，该模型不如DPC模型的收敛性好；而DPC模型中受拉采用Rankine模型的较好。
因此，建议采用DPC HSD2模型或DPC Rankine HSD2模型，实际应用时可采用二者分析比较。从计算过程和计算结果可以看出，SOLID185/186支持的DPC模型模拟混凝土分析，确实比SOLID65单元强很多，强烈推荐使用。
声明：原创文章，欢迎留言与我讨论，如需转载留言
