算例分享：MDOF体系地震波响应分析

本文给出一个单向水平地震波作用下的多自由度悬臂结构时程分析例题。

不计质量的柱高18m，截面特性为：A=0.0311m²，IYY=IZZ=0.0038m⁴，IXX=0.0076m⁴，Y、Z方向截面外轮廓尺寸均为1.0m。在柱高的3m、6m、9m、12m、15m、18m处各有一个集中质量M=1000kg。此悬臂结构受到幅值为70cm/s²的水平地震波作用，持续时间20秒，结构阻尼比按2%计算。

本例题通过APDL命令流进行建模和分析。具体分析过程如下。

1.建立分析模型

执行如下命令流，得到如下图所示的分析模型。

/PREP7

ET,1,188

KEYOPT,1,3,3

ET,2,21

KEYOPT,2,3,2

R,1,1000

mp,ex,1,2e11

mp,prxy,1,0.3

SECTYPE,   1, BEAM, ASEC, , 0  

SECOFFSET, CENT

SECDATA,0.0311,0.0038,0,0.0038,0,0.0076,0,0,0,0,1.0,1.0

N,1,        $     N,7,0.0,18.0,0.0    $     Fill

E,1,2      $     EGEN, 6,1,ALL

TYPE,2

*DO,I,2,7

E,I

*ENDDO

D,1,ALL,0.0

D,ALL,UZ,0.0

FINISH

2.模态分析

为了计算阻尼系数，首先通过下列命令流进行模态分析。

!分析选项设置与求解

/SOLU    !进入求解器

ANTYPE,2

MODOPT,lanb,6

MXPAND,6, , ,YES

SOLVE

FINISH

/POST1

SET,list

FINISH

模态分析完成后，得到各阶自振频率列表，如下图所列：

取结构的第1阶自振频率f1和第6阶自振频率f6，根据阻尼比2%计算质量阻尼系数、刚度阻尼系数如下： 

 α = 4π*f1 *f6*ξ/( f1 +f6)=0.549

 β =ξ/π/(f1 +f6)=0.0000559

 

3.瞬态分析

下面采用完全法进行瞬态分析，分析命令流文件如下。

/SOLU    !进入求解器

ANTYPE,TRANS      !定义分析类型

NN=1000                     !时程曲线有NN个点

*DIM,AC_X,,NN

*VREAD,AC_X(1),wave,TXT,

(F10.3)

TRNOPT,FULL

ALPHAD, 0.549

BETAD, 0.0000559

*DO,I,1,NN

!施加加速度荷载

ACEL,AC_X(I)

TIME,0.02*I                !设置时间点

OUTRES,ALL,ALL

SOLVE                        !求解

*ENDDO

FINISH

/POST26

NSOL,2,7,U,X,

PLVAR,2

计算完成后，通过上述命令查看顶端质量点的水平位移时间历程如图所示。