算例分享：平板网架结构的温度应力计算
本文给出一个平板网架结构的计算实例。
如图所示的正方形平面的平板网架，上弦平面尺寸为5.0m×5.0m，下弦平面尺寸为4.0m×4.0m，上下弦平面杆件长度均为1.0m，网架的高度（上下弦平面之间的垂直距离）为0.7m。上弦平面周边节点均铰支，其余节点和下弦平面均自由。杆件材料采用钢材，密度7.8×103kg/m3，弹性模量207GPa，泊松比0.3，线膨胀系数1.2×10-5/℃，计算这一网架结构在温度均匀降低30℃情况下的内力以及变形情况。
本例采用命令流方式进行操作。网架杆件采用LINK180单元模拟，在整个结构上施加均匀的温度变化，得到结构的变形和内力分布，各杆件的轴力通过ETABLE定义为单元表，再通过PLLS绘制结构的轴力图。
1. 建立分析模型
采用直接法建模，单位采用kg-N-m。通过下列命令流建立分析模型。
/PREP7
ET,1,LINK180
sectype,1,link
secdata, 4.91E-4
MP,EX,1,2.07e11 !弹性模量
MP,PRXY,1,0.3 !泊松比
MP,DENS,1,7800 !密度
MP,ALPX,1,1.2e-5
*DO,I,1,6,1
N,I,0.0,(I-1)*1.0,0.0
*ENDDO
NGEN,6,6,ALL,,,1.0,0.0,0.0 !节点复制
*DO,I,37,41,1
N,I,0.5,(I-37)*1.0+0.5,-0.7
*ENDDO
NGEN,5,5,37,41,1,1.0,0.0,0.0 !节点复制
*DO,I,1,31,6 !外循环
*DO,J,1,5,1 !内循环
E,I+J-1,I+J
*ENDDO
*ENDDO
*DO,I,1,30,1
E,I,I+6
*ENDDO
*DO,I,37,57,5 !外循环
*DO,J,1,4,1 !内循环
E,I+J-1,I+J
*ENDDO
*ENDDO
*DO,I,37,56,1
E,I,I+5
*ENDDO
*DO,I,37.0,57.0,5.0
*DO,J,1.0,5.0,1.0
E,I+J-1,1.2*I-43.4+J-1
E,I+J-1,1.2*I-43.4+J
E,I+J-1,1.2*I-43.4+J+5
E,I+J-1,1.2*I-43.4+J+6
*ENDDO
*ENDDO
/ESHAPE,1.0
EPLOT
FINI !退出前处理器
2.加载及计算
约束上弦周边节点的全部自由度，采用TUNIF命令施加均匀温度变化并求解。采用下列命令流实现加载以及计算。
/SOLU !进入求解器
NSEL,S,LOC,X,-0.1,0.1
NSEL,A,LOC,X,4.9,5.1
NSEL,A,LOC,Y,-0.1,0.1
NSEL,A,LOC,Y,4.9,5.1
D,ALL,ALL
allsel,all
TUNIF,-30
Solve !求解
FINI !退出求解器
下图所示为施加约束后的网架模型显示情况。
3.结果后处理
(1)整体变形观察
/POST1 !进入通用后处理器
SET,FIRST !读入结果文件
/VIEW, 1 ,,-1 !改变视图角度
/REP,FAST !重新绘图
PLDISP,0 !绘制结构变形图
(2)绘制变形等值线图
改变视图到合适的方位，通过下列命令绘制结构的变形等值线，如图4-17所示。
PLNSOL,U,Z,1,1 !绘制结构竖向位移分布等值线图
(3)绘制结构轴力图
改变视图到合适的方位，通过下列命令定义单元表并绘制结构轴力图，如下图所示。
ETABLE,AxialF,SMISC, 1 !定义单元表
PLLS,AXIALF,AXIALF,1,0 !绘制结构的轴力图
