ANSYS特征值屈曲分析之SFA加载诡异

SFA为几何模型的面(AREA)施加分布荷载的命令，提供了极大便利，因此较为常用。

你肯定用SFA施加过荷载吧，在静力分析或动力分析时正常，但在特征值屈曲分析时，用SFA施加面荷载会出现很大的误差，甚至是诡异的结果，不妨用下面几个例子说明该问题。

例1：截面为20mm×50mm高为1000mm的悬臂受压柱，材料参数如命令流。分别采用SFA（SFE或SF同SFA）施加面荷载、F施加等效的节点荷载，计算命令流和结果如下。

FINISH
/CLEAR$/PREP7
A=20$B=50$L=1000
BLC4,,,A,L,B
ET,1,SOLID185
MP,EX,1,2.1E5$MP,PRXY,1,0.3
ESIZE,10$MSHKEY,1$VMESH,ALL
ASEL,S,LOC,Y,0$DA,ALL,ALL
!不同的加载方式分别执行该部分,不再注释掉
!采用SFA施加均布面压力
ASEL,S,LOC,Y,L
SFA,ALL,1,PRES,1
ASEL,ALL
!用SFE施加均布压力
NSEL,S,LOC,Y,L
ESLN,S
SFE,ALL,4,PRES,,1
ALLSEL,ALL
!用SF施加均布压力
NSEL,S,LOC,Y,L$SF,ALL,PRES,1
NSEL,ALL
!采用与SFA完全等效的F施加节点荷载
NSEL,S,LOC,Y,L!
NSEL,R,LOC,Z,1,B-1
NSEL,U,LOC,X,10
F,ALL,FY,-50
NSEL,S,LOC,Y,L!!
NSEL,R,LOC,Z,1,B-1!
NSEL,R,LOC,X,10
F,ALL,FY,-100
NSEL,S,LOC,Y,L!!!!
NSEL,U,LOC,Z,1,B-1
NSEL,U,LOC,X,10.0
F,ALL,FY,-25
NSEL,S,LOC,Y,L!!!!!!
NSEL,U,LOC,Z,1,B-2
NSEL,R,LOC,X,10.00
F,ALL,FY,-50$NSEL,ALL
!完全等效-单元大小不一时-F施加节点荷载
!使用函数ARNODE和NDNEXT
NSEL,S,LOC,Y,L!!!!!!!
ESLN,S!
*GET,NT,NODE,,COUNT
*GET,NI,NODE,,NUM,MIN
*DO,I,1,NT
F,NI,FY,-ARNODE(NI)*1
NI=NDNEXT(NI)
*ENDDO
ALLSEL,ALL!!
!用F施加近似的节点荷载
NSEL,S,LOC,Y,L!!!!!!!!!
*GET,NT,NODE,,COUNT!!
F,ALL,FY,-1000/NT
NSEL,ALL!!
!获得静力解
/SOLU$PSTRES,ON$SOLVE$FINISH
!特征值屈曲分析
/SOLU$ANTYPE,1
BUCOPT,LANB,8
SOLVE
/POST1$SET,LIST

悬臂受压柱

SFA加载(诡异结果)
SET TIME/FREQ LOAD STEP SUBSTEP
1 -245.57 1 1
2 -41.008 1 2
3 70.309 1 3
4 222.89 1 4
5 419.16 1 5
6 631.35 1 6
7 1062.9 1 7
8 1319.1 1 8
完全等效的F加载(正确!)
1 17.581 1 1
2 108.47 1 2
3 158.14 1 3
4 438.77 1 4
5 858.53 1 5
6 968.92 1 6
7 1416.0 1 7
8 2109.2 1 8

（1）采用欧拉临界力计算，前两阶分别为17.272和107.95，与F加载吻合。而SFA特征值及其对应的失稳模态很难理解，且结果明显不正确。

（2）SFE、SF与SFA计算结果相同，都不正确。

（3）采用与SFA完全等效的节点荷载并用F施加或近似等效（平均分配）的F结果相同。

例2：同上几何参数，改为悬臂梁的侧倾屈曲分析。

FINISH$/CLEAR$/PREP7!
!定义悬臂梁截面尺寸和长度参数
A=20$B=50$L=1000!
!创建模型并网分
BLC4,,,A,B,L
ET,1,SOLID185!
MP,EX,1,2.1E5$MP,PRXY,1,0.30
ESIZE,10$MSHKEY,1$VMESH,ALL!
ASEL,S,LOC,Z,0$DA,ALL,ALL
!直接SFA施加均布荷载1
ASEL,S,LOC,Y,B
SFA,ALL,1,PRES,1$ASEL,ALL
!与SFA完全等效的F加载-面积分配
NSEL,S,LOC,Y,B$ESLN,S
*GET,NT,NODE,,COUNT!!!
*GET,NI,NODE,,NUM,MIN!!
*DO,I,1,NT$F,NI,FY,-ARNODE(NI)*1
NI=NDNEXT(NI)$*ENDDO
ALLSEL,ALL!必须的
!节点平均分配的F加载
NSEL,S,LOC,Y,B
*GET,NT,NODE,,COUNT!!!!
F,ALL,FY,-20000/NT
NSEL,ALL!!!!
/SOLU$PSTRES,ON
SOLVE$FINISH
/SOLU$ANTYPE,1!
BUCOPT,LANB,8$SOLVE
/POST1$SET,LIST!!!!
SFA加载
SET TIME/FREQ LOAD STEP SUBSTEP
1 -24.245 1 1
2 -20.211 1 2
3 -8.9582 1 3
4 -5.9315 1 4
5 5.9306 1 5
6 8.9594 1 6
7 20.214 1 7
8 24.245 1 8
!全完等效的F加载
1 -28.227 1 1
2 -20.530 1 2
3 -12.900 1 3
4 -5.3353 1 4
5 4.9111 1 5
6 12.281 1 6
7 19.781 1 7
8 27.374 1 8
!平均分配的F加载
1 -28.081 1 1
2 -20.424 1 2
3 -12.833 1 3
4 -5.3073 1 4
5 4.8873 1 5
6 12.220 1 6
7 19.682 1 7
8 27.236 1 8

（1）负特征值可以理解，详见文章《ANSYS屈曲分析之负特征值疑惑》。

（2）仅比较SFA和F正特征值，误差达27%之高（第6阶）。结合例1结果，说明SFA加载结果不正确。

梁的侧倾屈曲

例3：带加劲板悬臂圆筒的受压屈曲。参数详见命令流中。

FINISH$/CLEAR$/PREP7$R=200
T=12$H=8000$CYL4,,,R-T/2,,,,H
VDELE,ALL$ALLSEL,ALL
*DO,I,1,7$WPOFF,,,1000
ASBW,ALL$*ENDDO
WPROTA,,90$ASBW,ALL
WPROTA,,,90$ASBW,ALL
ASEL,S,LOC,Z,0
AGEN,8,ALL,,,,,1000
ALLSEL,ALL$NUMMRG,ALL
ET,1,SHELL181$MP,EX,1,2.1E5
MP,PRXY,1,0.3$R,1,12
AATT,1,1,1$MSHKEY,1
ESIZE,2*T$AMESH,ALL
ASEL,S,LOC,Z,0.0$DA,ALL,ALL
!SFA施加均布荷载
ASEL,S,LOC,Z,H
SFA,ALL,1,PRES,-1$ALLSEL,ALL
!F施加等效节点荷载
ASEL,S,LOC,Z,H!!!
NSLA,S,1$ESLA,S
*GET,NT,NODE,,COUNT!!!!!!
*GET,NI,NODE,,NUM,MIN!
*DO,I,1,NT$F,NI,FZ,-ARNODE(NI)*1
NI=NDNEXT(NI)$*ENDDO!
ALLSEL,ALL!!!!
/SOLU$PSTRES,ON$SOLVE
/SOLU$ANTYPE,1$NM=15
BUCOPT,LANB,NM
MXPAND,NM,0,0,YES
SOLVE!!
/POST1$SET,LIST!

柱壳屈曲

（1）SFA加载的计算结果很诡异，且难以理解。

（2）采用F加载的结果正常且与BEAM189或理论解吻合。

因此，在特征值屈曲分析时，强烈建议使用F或FK加载，谨慎使用SFA/SFE/SF加载（对实体单元面或壳单元面加载都有影响）。文中给出了采用ARNODE替代SFA的方法，当单元形状和大小不同时便于处理。

在静力或动力分析时，SFA和F未见有多大差别。

或许是SFA是随动荷载，而F是定向荷载；亦或是SFA的BUG，原因不详。

或许你以前用SFA加载做过特征值屈曲分析，建议改一下加载方式再核实一下，也许计算结果是错误的。

或许是版本问题，如果你的版本不存在这个问题，烦请留言告知。

（因文章检查重复句子，有些就只好用$并行了，如果执行有问题在$处换行解决。）