ANSYS惯性释放IRLF“放飞”无约束的自由结构

翻开材料力学、结构力学或弹性力学等教科书，常常会发现无约束的“自由结构”，即自平衡结构，如图1所示的(a)自平衡框架、(b)板的剪切和(c)杆件的自由扭转等。此类结构因无约束存在可能的刚体位移，从而导致ANSYS因约束不足而退出分析。有些情况下，可以采用荷载和结构的对称性，施加一定的对称约束或部分模型解决约束不足的问题；但是，更多实际情况可能无法施加对称约束，此时应力释放就可大显身手，从而“放飞”（分析求解）自由结构。

应力释放命令IRLF可参考ANSYS的HELP或《ANSYS工程结构数值分析》。在求解全自由结构或自平衡结构的内力和变形时，可施加节点的“虚约束”，该节点约束仅仅为防止刚体位移或刚体转动所必须的约束（如对2D结构，须施加3个自由度约束；对3D结构须施加6个自由度约束）。

需要注意的是惯性释放仅用于静态分析，且非线性、子结构、点单元及轴对称单元等不支持惯性释放，梁单元和层壳单元的质心偏置和变截面梁单元也不支持惯性释放。要利用惯性释放，必须输入材料的质量密度。下面以几个典型例子说明惯性释放的用法。

例1：如图2所示的结构特性不对称的框架，详细参数见命令流。

FINISH$/CLEAR$/PREP7
K,1$K,2,5$K,3,5,5$K,4,0,5
L,1,2$L,2,3$L,3,4
ET,1,BEAM189$MP,EX,1,2.1E11
MP,PRXY,1,0.3$MP,DENS,1,7800
SECTYPE,1,BEAM,RECT
SECDATA,0.2,0.2
SECTYPE,2,BEAM,RECT
SECDATA,0.2,0.3
SECTYPE,3,BEAM,RECT
SECDATA,0.2,0.4
LSEL,S,,,1$LATT,1,,1,,,4,1
LSEL,S,,,2$LATT,1,,1,,,4,2
LSEL,S,,,3$LATT,1,,1,,,1,3$LSEL,ALL
LESIZE,ALL,,,10$LMESH,ALL
!打开惯性释放,对48点施加全约束
!可任意约束一个节点
/SOLU$IRLF,1$D,48,ALL
!施加一对集中力
F,NODE(0,0,0),FY,1000
F,NODE(0,5,0),FY,-1000
SOLVE$FINISH$/POST1
PLNSOL,U,Y
!定义单元表，绘制弯矩图
ETABLE,MI,SMISC,2
ETABLE,MJ,SMISC,15
PLLS,MI,MJ,-1
!约束反力列表，反力等于零或几乎为零
PRRSOL

本例中的约束节点可以任选，也可以是施加荷载的节点。通过弯矩图和约束反力结果可以验证计算结果的正确性，也可通过改变立柱刚度验证变形的正确性。如果全部为等截面，则可通过对称结构的分析检验惯性释放的正确性。

例2：如图3所示的受剪平板的计算分析。采用SHELL181单元模拟，剪切荷载45MPa考虑板厚和边长分后，平均分布在边上的各个节点上；约束节点任取模型中的一个节点。按弹性力学假定计算的这种受剪板的正应力为零，剪应力数值等于剪切荷载。但因有限元和力学假定有一定差别，所以在去除角部一定影响后，ANSYS解与理论解一致。命令流如下：

FINISH$/CLEAR$/PREP7$A=3$B=2
TH=0.03$T0=45E6$BLC4,,,A,B
ET,1,SHELL181$MP,EX,1,2.1E11
MP,PRXY,1,0.1$MP,DENS,1,7800
R,1,TH$ESIZE,0.05$MSHKEY,1
AMESH,ALL
NSEL,S,LOC,X,0
*GET,N1,NODE,,COUNT
F,ALL,FY,T0*B*TH/N1
NSEL,S,LOC,X,A
*GET,N2,NODE,,COUNT
F,ALL,FY,-T0*B*TH/N2
NSEL,S,LOC,Y,0
*GET,N3,NODE,,COUNT
F,ALL,FX,T0*A*TH/N3
NSEL,S,LOC,Y,B
*GET,N4,NODE,,COUNT
F,ALL,FX,-T0*A*TH/N4$NSEL,ALL
!约束某个角节点并求解
/SOL$IRLF,1$D,1,ALL$SOLVE
/POST1$PLNSOL,U,SUM
PLNSOL,S,X
!去掉角部范围影响的剪应力
NSEL,S,LOC,X,0.5,2.5
NSEL,R,LOC,Y,0.5,1.5
ESLN,S,1$PLNSOL,S,XY

从图中可以看出，整个模型的角部范围还是有较大的正应力，去掉其影响后，板中剪应力与理论解几乎一样，虽然正应力还存在，但与剪应力比较，已经很小了。

例3：如图4所示自由扭转杆件，计算杆件的剪应力。众所周知，自由扭转存在翘曲位移，但翘曲位移不受约束，否则就是约束扭转问题了，采用惯性释放只需约束任一节点，可满足该条件。另外的关键是如何施加荷载，如果采用刚性面的方法有可能限制截面的翘曲变形，因此本例采用截面中线剪力流相同的概念施加两端节点荷载，如图4中所示。同例3一样，在绘制剪应力图时，去掉一个梁高端部影响，可以验证ANSYS模拟解与理论解决的误差在3%以内。

!建模几何模型并生成有限元模型
FINISH$/CLEAR$/PREP7$L=10
A=1.8$B=1.2$T1=0.024$T2=0.016
TT=2E6$C0=2*(A-T2)*(B-T1)
F10=TT/C0*(A-T2)$F20=TT/C0*(B-T1)
BLC4,,,L,B$AGEN,2,ALL,,,,,A
WPROTA,,90$BLC4,,,L,A
AGEN,2,3,,,,B$NUMMRG,ALL
ET,1,SHELL181$MP,EX,1,2E11
MP,PRXY,1,0.3$MP,DENS,1,7820
R,1,T1$R,2,T2
ASEL,S,LOC,Z,0$ASEL,A,LOC,Z,A
AATT,1,2,1
ASEL,S,LOC,Y,0$ASEL,A,LOC,Y,B
AATT,1,1,1
ASEL,ALL$MSHKEY,1$ESIZE,0.25
AMESH,ALL!
!施加截面各边节点荷载
!略复杂些，8条边分别施加
NSEL,S,LOC,X,0$NSEL,R,LOC,Z,0
*GET,N1,NODE,,COUNT!!
F,ALL,FY,F20/N1
NSEL,S,LOC,X,0$NSEL,R,LOC,Z,A
*GET,N2,NODE,,COUNT!!
F,ALL,FY,-F20/N2
NSEL,S,LOC,X,0$NSEL,R,LOC,Y,0
*GET,N3,NODE,,COUNT!!
F,ALL,FZ,-F10/N3
NSEL,S,LOC,X,0$NSEL,R,LOC,Y,B
*GET,N4,NODE,,COUNT!!
F,ALL,FZ,F10/N4
NSEL,S,LOC,X,L$NSEL,R,LOC,Z,0
*GET,N1,NODE,,COUNT!
F,ALL,FY,-F20/N1
NSEL,S,LOC,X,L$NSEL,R,LOC,Z,A
*GET,N2,NODE,,COUNT!
F,ALL,FY,F20/N2
NSEL,S,LOC,X,L$NSEL,R,LOC,Y,0
*GET,N3,NODE,,COUNT!
F,ALL,FZ,F10/N3
NSEL,S,LOC,X,L$NSEL,R,LOC,Y,B
*GET,N4,NODE,,COUNT!!!
F,ALL,FZ,-F10/N4$ALLSEL,ALL
!惯性释放打开，施加一个节点的约束
/SOLU$IRLF,1$D,1,ALL$SOLVE
/POST1$PLNSOL,U,SUM!
!取一个梁高范围外的单元
NSEL,S,LOC,X,A,L-A
ESLN,S,1
PLNSOL,S,XY
PLNSOL,S,XZ
!理论剪应力
ST1=TT/C0/T1$ST2=TT/C0/T2$*STAT

上述三例给出了惯性释放在静力分析中的应用和命令流，并与相关理论结果进行了验证。对于绝大多数实际工程结构而言，都有明确的约束，不必使用惯性释放。而对某些理论解的验证时，其力学模型往往缺少约束条件，而ANSYS静力分析又不能缺席约束条件，在模型不太容易利用对称性施加约束时，采用惯性释放往往成为计算分析的首选策略。